<xsl:when> |
Diese Anweisung definiert einen Zweig eines <xsl:choose>-Elements. Sie ist das Äquivalent zur Java-Anweisung case.
Kategorie
Untergeordnete Anweisung (<xsl:when> ist immer dem Element <xsl:choose> untergeordnet)
Obligatorische Attribute
test Dieses Attribut enthält einen Booleschen Ausdruck, der ausgewertet wird. Ergibt der Ausdruck den Wert true , wird der Inhalt des Elements < xsl:when > verarbeitet, andernfalls wird der Inhalt von < xsl:when > ignoriert.
Optionale Attribute
Keine
Inhalt
Eine XSLT-Vorlage.
Übergeordnetes Element
<xsl:choose>
Definition
XSLT-Abschnitt 9.2, Bedingte Verarbeitung mit xsl:choose
Beispiel
Das nachfolgende Beispiel verwendet ein <xsl:choose>-Element sowie drei <xsl:when>-Elemente, um nacheinander einen Satz an Werten zu durchschreiten. Zunächst werden für jedes <listitem>-Element Reihen einer HTML-Tabelle generiert:
    <?xml version="1.0"?>
    <list xml:lang="en">
      <title>Albums I've bought recently:</title>
      <listitem>The Sacred Art of Dub</listitem>
      <listitem>Only the Poor Man Feel It</listitem>
      <listitem>Excitable Boy</listitem>
      <listitem xml:lang="sw">Aki Special</listitem>
      <listitem xml:lang="en-gb">Combat Rock</listitem>
      <listitem xml:lang="zu">Talking Timbuktu</listitem>
      <listitem xml:lang="jz">The Birth of the Cool</listitem>
    </list>
Im Stylesheet werden Sie Tabellenzeilen mit den Hintergrundfarben mintcream, lavender, whitesmoke und papayawhip erzeugen. Für jedes <listitem>-Element im Ausgangsdokument erzeugt eines der <xsl:when>-Elemente (bzw. der <xsl:otherwise>-Elemente) die richtige Farbe.
    <?xml version="1.0"?>
    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

      <xsl:output method="html"/>

      <xsl:template match="/">
        <html>
          <head>
            <title>
              <xsl:value-of select="list/title"/>
            </title>
          </head>
          <body>
            <h1><xsl:value-of select="list/title"/></h1>
            <table border="1">
              <xsl:for-each select="list/listitem">
                <tr>
                  <td>
                    <xsl:attribute name="bgcolor">
                      <xsl:choose>
                        <xsl:when test="@bgcolor">
                          <xsl:value-of select="@bgcolor"/>
                        </xsl:when>
                        <xsl:when test="position() mod 4 = 0">
                          <xsl:text>papayawhip</xsl:text>
                        </xsl:when>
                        <xsl:when test="position() mod 4 = 1">
                          <xsl:text>mintcream</xsl:text>
                        </xsl:when>
                        <xsl:when test="position() mod 4 = 2">
                          <xsl:text>lavender</xsl:text>
                        </xsl:when>
                        <xsl:otherwise>
                          <xsl:text>whitesmoke</xsl:text>
                        </xsl:otherwise>
                      </xsl:choose>
                    </xsl:attribute>
                    <xsl:value-of select="."/>
                  </td>
                </tr>
              </xsl:for-each>
            </table>
          </body>
        </html>
      </xsl:template>

    </xsl:stylesheet>
Hier das Ergebnis, wenn Sie das XML-Ausgangsdokument mit diesem Stylesheet verarbeiten:
    <html>
    <head>
    <META http-equiv="Content-Type" content="text/html; charset=UTF-8">
    <title>Albums I've bought recently:</title>
    </head>
    <body>
    <h1>Albums I've bought recently:</h1>
    <table border="1">
    <tr>
    <td bgcolor="mintcream">The Sacred Art of Dub</td>
    </tr>
    <tr>
    <td bgcolor="lavender">Only the Poor Man Feel It</td>
    </tr>
    <tr>
    <td bgcolor="whitesmoke">Excitable Boy</td>
    </tr>
    <tr>
    <td bgcolor="papayawhip">Aki Special</td>
    </tr>
    <tr>
    <td bgcolor="mintcream">Combat Rock</td>
    </tr>
    <tr>
    <td bgcolor="lavender">Talking Timbuktu</td>
    </tr>
    <tr>
    <td bgcolor="whitesmoke">The Birth of the Cool</td>
    </tr>
    </table>
    </body>
    </html>
Alle <td>-Elemente mit den Hintergrundfarben papayawhip, mintcream oder lavender wurden von einem der <xsl:when>-Elemente erzeugt.