<xsl:message> |
Diese Anweisung dient zum Senden einer Nachricht. Wie die Nachricht versendet wird, kann für verschiedene XSLT-Prozessoren variieren, typischerweise wird sie aber an das Standardausgabegerät gesendet. Dieses Element eignet sich für die Fehlersuche in Stylesheets.
Kategorie
Anweisung
Obligatorische Attribute
Keine
Optionale Attribute
terminate= " yes " | " no " Besitzt dieses Attribut den Wert yes , so bricht der XSLT-Prozessor nach der Ausgabe dieser Nachricht die Ausführung ab. Der Standardwert für dieses Attribut ist no . Wenn < xsl:message > den Prozessor nicht beendet, wird die Nachricht gesendet und die Verarbeitung fortgesetzt.
Inhalt
Eine XSLT-Vorlage
Übergeordnetes Element
<xsl:message> erscheint innerhalb einer Template.
Definition
XSLT-Abschnitt 13, Nachrichten
Beispiel
Das nachfolgende Stylesheet verwendet das Element <xsl:message>, um die Umwandlung eines XML-Dokuments nachzuverfolgen. Es wird wieder die Liste der in letzter Zeit gekauften Alben verwendet:
    <?xml version="1.0"?>
    <list xml:lang="en">
      <title>Albums I've bought recently:</title>
      <listitem>The Sacred Art of Dub</listitem>
      <listitem>Only the Poor Man Feel It</listitem>
      <listitem>Excitable Boy</listitem>
      <listitem xml:lang="sw">Aki Special</listitem>
      <listitem xml:lang="en-gb">Combat Rock</listitem>
      <listitem xml:lang="zu">Talking Timbuktu</listitem>
      <listitem xml:lang="jz">The Birth of the Cool</listitem>
    </list>
Alle gekauften Alben werden in einer HTML-Tabelle aufgelistet, wobei die einzelnen Zeilen alternierende Hintergrundfarben erhalten. Das Stylesheet verwendet ein <xsl:choose>-Element innerhalb eines <xsl:attribute>-Elements, um den Wert des Attributs bgcolor zu bestimmen. Wird ein bestimmtes <listitem> in ein HTML-<tr> mit der Hintergrundfarbe lavender konvertiert, wird eine Glückwunschnachricht ausgegeben:
    <?xml version="1.0"?>
    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

      <xsl:output method="html"/>

      <xsl:template match="/">
        <html>
          <head>
            <title>
              <xsl:value-of select="list/title"/>
            </title>
          </head>
          <body>
            <h1><xsl:value-of select="list/title"/></h1>
            <table border="1">
              <xsl:for-each select="list/listitem">
                <tr>
                  <td>
                    <xsl:attribute name="bgcolor">
                      <xsl:choose>
                        <xsl:when test="position() mod 4 = 0">
                          <xsl:text>papayawhip</xsl:text>
                        </xsl:when>
                        <xsl:when test="position() mod 4 = 1">
                          <xsl:text>mintcream</xsl:text>
                        </xsl:when>
                        <xsl:when test="position() mod 4 = 2">
                          <xsl:text>lavender</xsl:text>
                          <xsl:message terminate="no">
                            <xsl:text>Table row #</xsl:text>
                            <xsl:value-of select="position()"/>
                            <xsl:text> is lavender!</xsl:text>
                          </xsl:message>
                        </xsl:when>
                        <xsl:otherwise>
                          <xsl:text>whitesmoke</xsl:text>
                        </xsl:otherwise>
                      </xsl:choose>
                    </xsl:attribute>
                    <xsl:value-of select="."/>
                  </td>
                </tr>
              </xsl:for-each>
            </table>
          </body>
        </html>
      </xsl:template>

    </xsl:stylesheet>
Beachten Sie, dass die XSLT-Spezifikation nicht festlegt, wie die Nachricht ausgegeben wird. Wenn Sie dieses Stylesheet mit Xalan 2.0.1 verwenden, erhalten Sie die folgenden Ergebnisse:
    file:///D:/O'Reilly/XSLT/bookSamples/AppendixA/message.xsl; Line 32; Column 51;
    Table row #2 is lavender!
    file:///D:/O'Reilly/XSLT/bookSamples/AppendixA/message.xsl; Line 32; Column 51;
    Table row #6 is lavender!
Xalan gibt Feedback zu dem Stylesheet, das die jeweilige Nachricht erzeugt hat. Saxon gibt sich kurz und freundlich.
    Table row #2 is lavender!
    Table row #6 is lavender!
Zur Abwechslung soll hier angeführt werden, wie XT das Element <xsl:message> verarbeitet:
    file:/D:/O'Reilly/XSLT/bookSamples/AppendixA/test4.xml:5: Table row #2 is lavender!
    file:/D:/O'Reilly/XSLT/bookSamples/AppendixA/test4.xml:9: Table row #6 is lavender!
XT gibt Informationen über die Zeile im XML-Ausgangsdokument, die die Meldung erzeugt hat.