<xsl:strip-space> |
Diese Anweisung legt fest, aus welchen Elementen des Ausgangsdokuments Leerräume entfernt werden sollen.
Kategorie
Element der obersten Ebene
Obligatorische Attribute
elements Dieses Attribut enthält eine durch Leerzeichen getrennte Liste an Ausgangsdokumentelementen, für die nicht signifikanter Leerraum entfernt werden soll. Mit "nicht signifikantem Leerraum" sind Textknoten gemeint, die nichts als Leerräume enthalten. Leerräume, die im Text vorkommen oder den Text umschließen, werden erhalten.
Optionale Attribute
Keine
Inhalt
Keiner. <xsl:strip-space> ist ein leeres Element.
Übergeordnetes Element
<xsl:strip-space> ist ein Element der obersten Ebene und kann nur dem Element <xsl:stylesheet> untergeordnet werden.
Definition
XSLT-Abschnitt 3.4, Entfernen von Leerräumen
Beispiel
Die Funktionsweise des Elements <xsl:strip-space> wird durch das folgende Stylesheet veranschaulicht:
    <?xml version="1.0"?>
    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

      <xsl:output method="text"/>
      <xsl:strip-space elements="listing"/>

      <xsl:variable name="newline">
    <xsl:text>
    </xsl:text>
      </xsl:variable>

      <xsl:template match="/">
        <xsl:value-of select="$newline"/>
        <xsl:value-of select="/code-sample/title"/>
        <xsl:value-of select="$newline"/>
        <xsl:for-each select="/code-sample/listing">
          <xsl:value-of select="."/>
        </xsl:for-each>
      </xsl:template>

    </xsl:stylesheet>
Dieses Stylesheet wird zur Verarbeitung des folgenden Dokuments verwendet:
    <?xml version="1.0"?>
    <code-sample>
      <title>Conditional variable initialization</title>
      <listing>
      <type>int</type> <variable>y</variable> = <constant>23</constant>;
      <type>int</type> <variable>x</variable>;

        <keyword>if</keyword> (<variable>y</variable> > <constant>10</constant>)
        <variable>x</variable> = <constant>5</constant>;
      <keyword>else</keyword>
        <keyword>if</keyword> (<variable>y</variable> > <constant>5</constant>)
          <variable>x</variable> = <constant>3</constant>;
      <keyword>else</keyword>
        <variable>x</variable> = <constant>1</constant>;
      </listing>
    </code-sample>
Hier die Ergebnisse:
    Conditional variable initialization
    inty = 23;
      intx;
        if (y > 10)
        x = 5;
      elseif (y > 5)
          x = 3;
      elsex = 1;
Beachten Sie, dass aus dem Element <listing> alle zusätzlichen Leerräume entfernt worden sind. Dazu gehören die Leerzeichen zwischen den verschiedenen Elementen in <listing>, z. B. <keyword>, <constant> und <variable>. Vergleichen Sie dieses Beispiel mit dem in der Beschreibung des Elements <preserve-space>.