unparsed-entity-uri()-Funktion |
Diese Funktion gibt den URI der nicht analysierbaren Entity des angegebenen Namens zurück. Wenn es eine solche Entity nicht gibt, liefert unparsed-entity-uri einen leeren String.
Eingaben
Der Name der nicht analysierbaren Entity.
Ausgabe
Der URI der nicht analysierbaren Entity des angegebenen Namens.
Definition
XSLT-Abschnitt 12.4, Diverse zusätzliche Funktionen
Beispiel
Nicht analysierbare Entities werden selten verwendet. Es handelt sich dabei um Nicht-XML-Daten wie bei der Entity author-picture im nachfolgenden XML-Dokument:
    <?xml version="1.0"?>
    <!DOCTYPE book [
      <!ENTITY author-picture SYSTEM "dougtidwell.jpg" NDATA JPEG>
    ]>
    <book>
      <prolog cover-image="author-picture"/>
      <body>
        <p>Pretend that lots of useful content appears here.</p>
      </body>
    </book>
Das folgende Stylesheet wird zur Verarbeitung der nicht analysierbaren Entity verwendet:
    <?xml version="1.0"?>
    <xsl:stylesheet version="1.0"
      xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

      <xsl:output method="text"/>

      <xsl:variable name="newline">
    <xsl:text>
    </xsl:text>
      </xsl:variable>

      <xsl:template match="/">
        <xsl:value-of select="$newline"/>
        <xsl:text>A test of the unparsed-entity-uri() function:</xsl:text>

        <xsl:value-of select="$newline"/>
        <xsl:value-of select="$newline"/>
        <xsl:text>   The cover image is located at </xsl:text>
        <xsl:value-of select="unparsed-entity-uri(/book/prolog/@cover-image)"/>
        <xsl:text>.</xsl:text>
        <xsl:value-of select="$newline"/>
      </xsl:template>

    </xsl:stylesheet>
Wenn das XML-Dokument mit diesem Stylesheet umgewandelt wird, entsteht folgendes Ergebnis:
    A test of the unparsed-entity-uri() function:

       The cover image is located at file:///D:/O'Reilly/dougtidwell.jpg.
Der URI der nicht analysierbaren Entity basiert auf dem Basis-URI des XML-Dokuments selbst.