<xsl:choose> |
Das Element <xsl:choose> ist die XSLT-Version der in vielen prozeduralen Programmiersprachen zu findenden switch- oder case-Anweisung.
Kategorie
Anweisung
Obligatorische Attribute
Keine
Optionale Attribute
Keine
Inhalt
Das Element enthält eines oder mehrere <xsl:when>-Elemente und möglicherweise auch ein einzelnes <xsl:otherwise>-Element. Das Element <xsl:otherwise> muss das letzte Element innerhalb der <xsl:choose>-Anweisung sein.
Übergeordnetes Element
<xsl:choose> erscheint innerhalb einer Vorlage.
Definition
XSLT-Abschnitt 9.2, Bedingte Verarbeitung mit xsl:choose
Beispiel
Das nachfolgende Beispiel verwendet <xsl:choose> dazu, die Hintergrundfarbe für die Zeilen in einer HTML-Tabelle auszuwählen. Es werden vier verschiedene Werte durchschritten und <xsl:choose> bestimmt den Wert des Attributs bgcolor im erzeugten HTML-Dokument. Es wird das folgende XML-Dokument verwendet:
    <?xml version="1.0"?>
    <list xml:lang="en">
      <title>Albums I've bought recently:</title>
      <listitem>The Sacred Art of Dub</listitem>
      <listitem>Only the Poor Man Feel It</listitem>
      <listitem>Excitable Boy</listitem>
      <listitem xml:lang="sw">Aki Special</listitem>
      <listitem xml:lang="en-gb">Combat Rock</listitem>
      <listitem xml:lang="zu">Talking Timbuktu</listitem>
      <listitem xml:lang="jz">The Birth of the Cool</listitem>
    </list>
Hier das Stylesheet:
    <?xml version="1.0"?>
    <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

      <xsl:output method="html"/>

      <xsl:template match="/">
        <html>
          <head>
            <title>
              <xsl:value-of select="list/title"/>
            </title>
          </head>
          <body>
            <h1><xsl:value-of select="list/title"/></h1>
            <table border="1">
              <xsl:for-each select="list/listitem">
                <tr>
                  <td>
                    <xsl:attribute name="bgcolor">
                      <xsl:choose>
                        <xsl:when test="position() mod 4 = 0">
                          <xsl:text>papayawhip</xsl:text>
                        </xsl:when>
                        <xsl:when test="position() mod 4 = 1">
                          <xsl:text>mintcream</xsl:text>
                        </xsl:when>
                        <xsl:when test="position() mod 4 = 2">
                          <xsl:text>lavender</xsl:text>
                        </xsl:when>
                        <xsl:otherwise>
                          <xsl:text>whitesmoke</xsl:text>
                        </xsl:otherwise>
                      </xsl:choose>
                    </xsl:attribute>
                    <xsl:value-of select="."/>
                  </td>
                </tr>
              </xsl:for-each>
            </table>
          </body>
        </html>
      </xsl:template>

    </xsl:stylesheet>
Mit Hilfe von <xsl:choose> wird die Hintergrundfarbe von jedem <td>-Element bestimmt. Hier das erzeugte HTML-Dokument, das die verschiedenen Hintergrundfarben durchschreitet.
    <html>
    <head>
    <META http-equiv="Content-Type" content="text/html; charset=UTF-8">
    <title>Albums I've bought recently:</title>
    </head>
    <body>
    <h1>Albums I've bought recently:</h1>
    <table border="1">
    <tr>
    <td bgcolor="mintcream">The Sacred Art of Dub</td>
    </tr>
    <tr>
    <td bgcolor="lavender">Only the Poor Man Feel It</td>
    </tr>
    <tr>
    <td bgcolor="whitesmoke">Excitable Boy</td>
    </tr>
    <tr>
    <td bgcolor="papayawhip">Aki Special</td>
    </tr>
    <tr>
    <td bgcolor="mintcream">Combat Rock</td>
    </tr>
    <tr>
    <td bgcolor="lavender">Talking Timbuktu</td>
    </tr>
    <tr>
    <td bgcolor="whitesmoke">The Birth of the Cool</td>
    </tr>
    </table>
    </body>
    </html>
Wie das HTML-Dokument in einem Browser angezeigt wird, sehen Sie in Abbildung A-5. Dokument-Cycling unter verschiedenen Hintergrundfarben