ISBINARY |
説明 値がバイナリデータとして保管されているかどうかを調べます。
戻り値 値がバイナリの場合は true、それ以外は false。
カテゴリ 決定関数
関数のシンタックス
    IsBinary(value)
関連項目 ToBinary、ToBase64、IsNumeric、YesNoFormat
パラメータ
例
    <!--- すべての ASCII 文字 (32 〜 255) から成る文字列を作成し、
         それらを連結 --->
    <cfset charData ="">
    <cfloop index="data" from="32" to="255">
       <cfset ch=chr(data)>
       <cfset charData=charData & ch>
    </cfloop>

    <b>次の文字列は、ASCII 表のすべての文字 (32 〜 255) を連結したものです。</b><br><br>
    <cfoutput>#htmleditformat(charData)#</cfoutput>
    <br><br>
    <!--- この文字列を Base 64 形式に変換したものを作成 --->
    <cfset data64=toBase64(charData)>
    <!--- 文字列からバイナリに変換 --->
    <cfset binaryData=toBinary(data64)>
    <!--- 本当にバイナリ値かどうかを確認 --->
    <cfif IsBinary(binaryData)>
        binaryData 変数はバイナリです。<br>
    </cfif>
    <!--- バイナリデータを Base 64 に戻す --->
    <cfset another64=toBase64(binaryData)>
    <cfif Not IsBinary(another64)>
        another64 変数はバイナリではありません。<br>
    </cfif>
    <!--- another64 と data64 を比較し、両者が一致することを確認 --->
    <cfif another64 eq data64>
       バイナリデータを Base 64 形式に戻したものは、元の文字列を Base 64 形式で
       表したものに一致しています。
    <cfelse>
       <h3>変換エラーです。</h3>
    </cfif>

VALUE |
数値または文字列です。