CREATEDATETIME |
説明 日付時刻オブジェクトを作成します。
戻り値 日付時刻の値
カテゴリ 日付および時刻関数
関数のシンタックス
    CreateDateTime(year, month, day, hour, minute, second)
関連項目 CreateDate、CreateTime、CreateODBCDateTime、Now、『ColdFusion MX 開発ガイド』の第3章の「ColdFusion 変数の使用」 の「ODBC がサポートされていない場合の日付時刻関数およびクエリー」
パラメータ
例
    <h3>CreateDateTime の例</h3>

    <CFIF IsDefined("form.year")>
    CreateDateTime で生成された日付値 :
    <CFSET yourDate = CreateDateTime(form.year, form.month, form.day,
    form.hour, form.minute, form.second)>

    <cfoutput>
    <ul>
       <li>CreateDate で設定した形式 :#CreateDate(form.year, form.month, form.day)#
       <li>CreateDateTime で設定した形式 :#CreateDateTime(form.year, form.month,
    form.day, form.hour, form.minute, form.second)#
       <li>CreateODBCDate で設定した形式 :#CreateODBCDate(yourDate)#
       <li>CreateODBCDateTime で設定した形式 :#CreateODBCDateTime(yourDate)#
    </ul>

    <p>同じ値を、DateFormat で形式設定できます。
    <ul>
       <li>CreateDate および DateFormat で設定した形式 :
          #DateFormat(CreateDate(form.year, form.month, form.day), "mmm-dd-yyyy")#
       <li>CreateDateTime および DateFormat で設定した形式 :
          #DateFormat(CreateDateTime(form.year, form.month, form.day,
    form.hour, form.minute, form.second))#
       <li>CreateODBCDate および DateFormat で設定した形式 :
          #DateFormat(CreateODBCDate(yourDate), "mmmm d, yyyy")#
       <li>CreateODBCDateTime および DateFormat で設定した形式 :
          #DateFormat(CreateODBCDateTime(yourDate), "d/m/yy")#
    </ul>
    </cfoutput>
    </CFIF>

    <CFFORM ACTION="createdatetime.cfm" METHOD="POST">
    <p>日付として表示する年、月、および日を整数形式で入力してください。
    <PRE>
    年   <CFINPUT TYPE="Text" NAME="year" VALUE="1998" VALIDATE="integer"
          REQUIRED="Yes">
    月   <CFINPUT TYPE="Text" NAME="month" VALUE="6" RANGE="1,12"
          MESSAGE="月 (1 〜 12) を入力してください。" VALIDATE="integer"
          REQUIRED="Yes">
    日   <CFINPUT TYPE="Text" NAME="day" VALUE="8" RANGE="1,31"
          MESSAGE="日 (1 〜 31) を入力してください。" VALIDATE="integer"
          REQUIRED="Yes">
    時   <CFINPUT TYPE="Text" NAME="hour" VALUE="16" RANGE="0,23"
          MESSAGE="時 (0 〜 23) を入力してください。" VALIDATE="integer"
          REQUIRED="Yes">
    分   <CFINPUT TYPE="Text" NAME="minute" VALUE="12" RANGE="0,59"
          MESSAGE="分 (0 〜 59) を入力してください。" VALIDATE="integer"
          REQUIRED="Yes">
    秒   <CFINPUT TYPE="Text" NAME="second" VALUE="0" RANGE="0,59"
          MESSAGE="秒 (0 〜 59) を入力してください。" VALIDATE="integer"
          REQUIRED="Yes">
    </PRE>
    <p><INPUT TYPE="Submit" NAME=""> <INPUT TYPE="RESET">
    </cfform>

YEAR |
0 〜 9999 の範囲の整数です。0 〜 29 の範囲の整数は 2000 〜 2029 に変換されます。30 〜 99 の範囲の整数は 1930 〜 1999 に変換されます。西暦 100 年より前の日付は指定できません。

MONTH |
1 (1 月) 〜 12 (12 月) の範囲の整数です。

DAY |
1 〜 31 の範囲の整数です。

HOUR |
0 〜 23 の範囲の整数です。

MINUTE |
0 〜 59 の範囲の整数です。

SECOND |
0 〜 59 の範囲の整数です。