CFTABLE |
説明 ColdFusion ページ内にテーブルを構築します。cftable タグでは、書式付きテキストとして、または、HTMLTable 属性を使用して、HTML テーブルにデータを表示します。HTML の table タグコードを記述したくない場合や、書式付きテキストとしてデータを表示できる場合に、このタグを使用します。 HTML で <pre> タグおよび </pre> タグを使用して定義された、書式付きテキストは、固定幅のフォントで表示されます。空白および改行は、pre タグ内の記述に従って表示されます。詳細については、HTML のリファレンスガイドを参照してください。 テーブルの列および行の仕様を定義するには、このタグ内でcfcolタグを使用します。
カテゴリ データ出力タグ
シンタックス
    <cftable
       query = "query_name"
       maxRows = "maxrows_table"
       colSpacing = "number_of_spaces"
       headerLines = "number_of_lines"
       HTMLTable
       border
       colHeaders
       startRow = "row_number">
       ...
    </cftable>
関連項目 cfcol、cfcontent、cflog、cfoutput、cfprocessingdirective、cftable、『ColdFusion MX 開発ガイド』の第20章の「データへのアクセスおよび取り出し」 の「データの取り出し」
使用方法 このタグでは、テーブルデータの配置、列幅の設定、および列のヘッダの定義が行われます。 このタグには、少なくとも 1 つの cfcol タグが必要です。また、cfcol タグおよび cftable タグはページ内で隣接させて配置する必要があります。このタグ内には、cfcol タグだけをネストできます。cftable タグはネストできません。 cfcol の header で指定されるテキストを表示するには、cfcol の header 属性と cftable の colHeader 属性を指定する必要があります。どちらか一方の属性だけを指定しても、ヘッダは表示されず、エラーも発生しません。
例
    <!--- この例では、cfcol タグと cftable タグを使用して、クエリーから返された情報の位置を揃えます。 --->
    <!--- このクエリーでは、cfdocexamples データソースから従業員情報を選択します。 --->
    <cfquery name = "GetEmployees" dataSource = "cfdocexamples">
       SELECT  Emp_ID, FirstName, LastName, EMail, Phone, Department
       FROM Employees
    </cfquery>

    <html>
    <body>
    <h3>cftable の例</h3>

    <!--- HTMLTable 属性を使用して、PRE 書式の情報としてではなく、 HTML テーブルとして cftable を表示して
    いることに注意してください。 --->
    <cftable query = "GetEmployees"
       startRow = "1" colSpacing = "3" HTMLTable>
    <!--- 各 cfcol タグでテーブル内の列の幅を設定し、セルに挿入するヘッダ情報、およびテキストまたは CFML を
    指定します。 --->
       <cfcol header = "<b>ID</b>"
          align = "Left"
          width = 2
          text  = "#Emp_ID#">

       <cfcol header = "<b>名前と電子メール</b>"
          align = "Left"
          width = 15
          text  = "<a href = ﾕmailto:#Email#ﾕ>#FirstName# #LastName#</A>">

       <cfcol header = "<b>電話番号</b>"
          align = "Center"
          width = 15
          text  = "#Phone#">
    </cftable>
    </body>
    </html>

QUERY |
| 必須
データを取り出す cfquery の名前です。

MAXROWS |
| オプション
テーブルに表示する行の最大数です。

COLSPACING |
| オプション
Default value: "2" 列間のスペースの数です。

HEADERLINES |
| オプション
Default value: "2" テーブルのヘッダに使用する線の数です (デフォルトでは、テーブルのヘッダと最初の行の間を 1 行空けます)。

HTMLTABLE |
| オプション
HTML 3.0 テーブルでデータを表示します。 値にかかわらず、この属性を使用すると、データが HTML テーブルで表示されます。

BORDER |
| オプション
テーブルの周囲に枠を表示します。 値にかかわらず、この属性を使用するとテーブルの周囲に枠が表示されます。 HTMLTable 属性を使用する場合のみ使用します。

COLHEADERS |
| オプション
列のヘッダを表示します。この属性を使用する場合、cfcol タグの header 属性を同時に使用してヘッダを定義する必要があります。 値にかかわらず、この属性を使用すると列のヘッダが表示されます。

STARTROW |
| オプション
Default value: "1" テーブルの 1 行目に配置するクエリー結果の行です。