CFCHARTSERIES |
説明 cfchart タグと共に使用します。このタグでは、棒グラフ、折れ線グラフ、円グラフなど、データを表示するチャートのスタイルを定義します。
カテゴリ データ出力タグ、拡張タグ
シンタックス
    <cfchartseries
       colorlist = "list">
       itemColumn="queryColumn"
       markerStyle="style"
       paintStyle="plain"、"raise"、"shade"、"light" のいずれか
       query="queryName"
       seriesColor="Hex value" または "Web color"
       seriesLabel="Label Text"
       type="type"
       valueColumn="queryColumn"
       dataLabelStyle="style"
    </cfchartseries>
関連項目 cfchart、cfchartdata、『ColdFusion MX 開発ガイド』の第31章の「チャートとグラフの作成」
ヒストリ ColdFusion MX 7: dataLabelStyle 属性および horizontalbar チャートタイプが追加されました。 ColdFusion MX 6.1: 補間の動作が変更されました。タグは、複数の系列を持つ折れ線グラフのデータポイントを補間するようになりました。 ColdFusion MX: このタグが追加されました。
使用方法 円グラフの場合、円の項目の色は次のように設定されます。 seriesColor 属性を省略すると、自動的に各項目の色が設定されます。 seriesColor 属性を指定すると、最初の項目に指定された色が付けられ、順にその後の各項目に自動的に色が付けられます。
例
    <!--- 次の例では、cfdocexamples データベース内の給与データを分析し、
    部門ごとの平均給与を示す棒グラフを作成します。 --->

    <!--- 未処理データをデータベースから取得します。 --->
    <cfquery name="GetSalaries" datasource="cfdocexamples">
    SELECT  Departmt.Dept_Name,
    Employee.Dept_ID,
    Employee.Salary
    FROM Departmt, Employee
    WHERE Departmt.Dept_ID = Employee.Dept_ID
    </cfquery>

    <!--- クエリーオブクエリーを使用して、各部門の統計データを使用する --->
    <!--- 新規クエリーを生成します。 --->
    <!--- AVG および SUM で統計を計算します。 --->
    <!--- GROUP BY で部門ごとの結果を生成します。 --->
    <cfquery dbtype = "query" name = "DataTable">
    SELECT
    Dept_Name,
    AVG(Salary) AS avgSal,
    SUM(Salary) AS sumSal
    FROM GetSalaries
    GROUP BY Dept_Name
    </cfquery>

    <!--- 生成された数値を千の位で四捨五入するように形式を設定し直します。 --->
    <cfloop index = "i" from = "1" to = "#DataTable.RecordCount#">
    <cfset DataTable.sumSal[i] = Round(DataTable.sumSal[i]/1000)*1000>
    <cfset DataTable.avgSal[i] = Round(DataTable.avgSal[i]/1000)*1000>
    </cfloop>

    <h1>従業員の給与の分析</h1>
    <!--- クエリーオブクエリーによる棒グラフ --->
    <cfchart format="flash"
    xaxistitle="Department"
    yaxistitle="Salary Average">

    <cfchartseries type="bar"
    query="DataTable"
    itemcolumn="Dept_Name"
    valuecolumn="avgSal" />
    </cfchart>

COLORLIST |
| オプション
各データポイントの色を設定します。cfchartseries の type 属性が pie、pyramid、area、horizontalbar、cone、cylinder、または step の場合に適用します。 16 進数の値またはサポートされる Web の色名のカンマ区切りリストです。名前のリストおよび 6 桁または 8 桁の 16 進数値については、cfchart の「使用方法」を参照してください。 16 進数の値を入力するには、"##xxxxxx" または "##xxxxxxxx" という形式を使用します。ここで、x は 0 ～ 9 または A ～ F です。シャープ記号 (#) は 2 つ使用するか、または使用しないでください。

ITEMCOLUMN |
| query 属性を指定している場合は必須
query 属性に指定されたクエリー内の列の名前です。グラフで表すデータポイントの項目ラベルを指定します。

MARKERSTYLE |
| オプション
Default value: "rectangle" 2 次元の折れ線グラフ、曲線グラフ、および散布グラフのデータポイントにマーカーとして表示するアイコンを設定します。 rectangle triangle diamond circle letter mcross snow rcross

PAINTSTYLE |
| オプション
Default value: "plain" データ系列のペイント表示スタイルを設定します。 plain: 一色の塗りつぶしです。 raise: ボタン状の外観です。 shade: 端部が濃くなるグラデーション塗りつぶしです。 light: 淡い色のグラデーション塗りつぶしです。

QUERY |
| オプション
グラフ化するデータを取得するための ColdFusion クエリーの名前です。

SERIESCOLOR |
| オプション
チャートの主要な要素 (棒グラフの棒など) の色です。円グラフの場合は、最初の項目の色を示します。 16 進数の値またはサポートされる色名です。名前のリストおよび 6 桁または 8 桁の 16 進数値については、cfchart タグの「使用方法」を参照してください。 16 進数の値を入力するには、"##xxxxxx" または "##xxxxxxxx" という形式を使用します。ここで、x は 0 ～ 9 または A ～ F です。シャープ記号 (#) は 2 つ使用するか、または使用しないでください。

SERIESLABEL |
| オプション
データ系列のラベルのテキストです。

TYPE |
| 必須
チャートの表示スタイルを設定します。 bar line pyramid area horizontalbar cone curve cylinder step scatter pie

VALUECOLUMN |
| query 属性を指定している場合は必須
query 属性に指定されたクエリー内の列の名前です。グラフで表すデータ値を指定します。

DATALABELSTYLE |
| オプション
Default value: "none" 系列の項目に色を適用する方法を指定します。 none: 何も出力しません。 value: データポイントの値です。 rowLabel: 行のラベルです。 columnLabel: 列のラベルです。 pattern: トータルグラフに対するパーセンテージを示す columnLabel の値など、列ラベル、値、および集計情報の組み合わせです。たとえば、Sales 55,000 20% of 277,000 などです。