CFGRIDCOLUMN |
説明 cfform タグ内で cfgrid タグと共に使用します。列を形式設定し、必要に応じてクエリーから列を挿入します。cfgridcolumn 内で使用するフォント属性と配置属性は、cfgrid 内で定義されているグローバルなフォント設定や配置設定よりも優先されます。
カテゴリ フォームタグ
シンタックス
    <cfgridcolumn
       name = "column_name"
       header = "header"
       width = "column_width"
       type = "type"
       display = "yes"、"no"
       select = "yes"、"no"
       font = "column_font"
       fontSize = "size"
       italic = "yes"、"no"
       bold = "yes"、"no"
       textColor = "web color"、"expression"
       bgColor = "web color"、"expression"
       dataAlign = "position"
    次の属性は Flash 形式にのみ適用されます。
       mask= "format mask"
    次の属性はアプレット形式にのみ適用されます。
       href = "URL"
       hrefKey = "column_name"
       target = "URL_target"
       headerFont = "font_name"
       headerFontSize = "size"
       headerItalic = "yes"、"no"
       headerBold = "yes"、"no"
       headerTextColor = "web color"
       headerAlign = "position"
       numberFormat = "format"
       values = "Comma-separated strings and/or numeric range"
       valuesDisplay = "Comma-separated strings and/or numeric range"
       valuesDelimiter = "delimiter character">
関連項目 cfgrid、cfgridrow、cfgridupdate、cfform、cfapplet、cfinput、cfselect、cfslider、cftextarea、cftree
ヒストリ ColdFusion MX 7: mask 属性、および通貨の type 属性値が追加されました。 ColdFusion MX: select="no" の場合の動作が変更されました。cfgrid selectmode 属性の値に関係なく、ユーザーはセルデータを選択および編集できません。セルをクリックすると、セルのボーダー (selectColor の値によってはセルの背景も) の色が変わりますが、セルのデータを編集することはできません。
メモ: | XML 形式では、ColdFusion MX はすべての属性を XML に渡します。用意された XSLT スキンでは、XML 形式のグリッドは処理または表示されませんが、アプレット形式および Flash 形式のグリッドは表示されます。
numberFormat のマスク文字 アプレット形式の場合に限り、次の numberFormat 属性のマスク文字を使用して、出力を米国式の数値形式や通貨形式に設定することができます。これらのマスク文字の使い方の詳細については、348ページのNumberFormatを参照してください。cfgridcolumn タグでは、国際数値形式はサポートされません。
文字 | 意味
--- | ---
_ | (アンダースコア) 桁プレースホルダーです。
9 | 桁プレースホルダーです。
. | (ピリオド) 必須の小数点の位置です。
0 | 必須の小数点の左または右に置かれ、0 (ゼロ) が埋め込まれます。
( ) | 数値が 0 より小さい場合は、マスクを丸括弧で囲みます。
+ | 正の数値の前にプラス記号を置き、負の数値の前にマイナス記号を置きます。
- | 正の数値の前にスペースを置き、負の数値の前にマイナス記号を置きます。
, | (カンマ) 3 桁ごとにカンマで区切ります。
L、C | マスク列の幅の中で数値を左揃えまたは中央揃えにします。L または C はマスクの先頭に指定する必要があります。デフォルトは右揃えです。
$ | 形式設定された数値の先頭にドル記号を置きます。マスクの先頭に指定します。
^ | (カレット) 右側の形式と左側の形式を区切ります。
mask 属性の日付時刻形式 日付時刻値は、デフォルトでは Flash で Oct 29 2004 11:03:21 のような表示形式を使ってグリッド列に表示されます。mask 属性を使用すると、日付または時刻を別の形式で表示できます。それらの形式について次の表で説明します。
パターン文字 | 説明
--- | ---
Y | 年。このパターン文字の数が 2 個の場合、年は 2 桁に切り捨てられます。それ以外の場合は 4 桁で表示されます。次の一連の例の 3 番めに示されているように、年はゼロでパディングすることができます。 例 : YY = 03 YYYY = 2003 YYYYY = 02003
M | 月。形式は次の条件によって決まります。 パターン文字の数が 1 個の場合、形式は 1 桁または 2 桁の数値と解釈されます。 パターン文字の数が 2 個の場合、形式は 2 桁の数値と解釈されます。 パターン文字の数が 3 個の場合、形式は短いテキストとして解釈されます。 パターン文字の数が 4 個の場合、形式はフルテキストとして解釈されます。 例 : M = 7 MM = 07 MMM = Jul MMMM = July
D | 月の日。 例 : D = 4 DD = 04 DD = 10
E | 曜日。形式は次の条件によって決まります。 パターン文字の数が 1 個の場合、形式は 1 桁または 2 桁の数値と解釈されます。 パターン文字の数が 2 個の場合、形式は 2 桁の数値と解釈されます。 パターン文字の数が 3 個の場合、形式は短いテキストとして解釈されます。 パターン文字の数が 4 個の場合、形式はフルテキストとして解釈されます。 例 : E = 1 EE = 01 EEE = Mon EEEE = Monday
A | AM/PM を示すインジケータ。
J | 1 日の時間 (0 ～ 23)。
H | 1 日の時間 (1 ～ 24)。
K | am/pm の時間 (0 ～ 11)。
L | am/pm の時間 (1 ～ 12)。
N | 分。 例 : N = 3 NN = 03
S | 秒。
その他のテキスト | その他のテキストをパターン文字に加えて、文字列をさらに細かく形式設定することができます。句読点、数字、すべての小文字を使用できます。大文字は、パターン文字として解釈される可能性があるため、使用しないようにする必要があります。 例 : EEEE, MMM.D, YYYY at H:NN A = Tuesday, Sept. 8, 2003 at 1:26 PM
例 次の例では、cfdocexamples データベースにある CourseList テーブルの特定のフィールドを更新します。cfgridcolumn タグを使用して、テーブルを構築します。
    <!--- gridEntered フィールドが存在する場合、フォームは送信されています。
          データベースを更新します。 --->
    <cfif IsDefined("form.gridEntered")>
       <cfgridupdate grid = "FirstGrid" dataSource = "cfdocexamples"
       tableName = "CourseList" keyOnly = "Yes">
    </cfif>

    <!--- データベースにクエリーを実行し、グリッドの埋め込みを行います。 --->
    <cfquery name = "GetCourses" dataSource = "cfdocexamples">
     SELECT Course_ID, Dept_ID, CorNumber,
         CorName, CorLevel, CorDesc
    FROM  CourseList
    ORDER by Dept_ID ASC, CorNumber ASC
    </cfquery>

    <html>
    <head>
    <title>cfgrid の例</title>
    </head>
    <body>
    <h3>cfgrid の例</h3>
    <I>コースの Name、Level、および Description に関する情報を更新することができます。</i>
    <!--- cfgrid コントロールを cfform タグで囲む必要があります。 --->
    <cfform action = "#CGI.SCRIPT_NAME#">
       <cfgrid name = "FirstGrid" width = "500"
             query = "GetCourses" colheaderbold="Yes"
             font = "Tahoma" rowHeaders = "No"
             selectColor = "Red" selectMode = "Edit" >
          <!--- cfgridcolumn タグがテーブルを整列し、表示を制御します。 --->
          <!--- 更新に必要なプライマリーキーを非表示にします。 --->
          <cfgridcolumn name = "Course_ID" display = "No">
          <!--- select="No" は効果があるとは思えません!!! --->
          <cfgridcolumn name = "Dept_ID" header = "Department"
             width="75" textcolor="blue" bold="Yes">
          <cfgridcolumn name = "CorNumber" header = "Course ##"
             width="65">
          <cfgridcolumn name = "CorName" header = "Name">
          <cfgridcolumn name = "CorLevel" header = "Level">
          <cfgridcolumn name = "CorDesc" header = "Description">
       </cfgrid>
       <br>
       <cfinput type="submit" name="gridEntered">
    </cfform>
    </body>
    </html>

NAME |
| 必須、
| すべて
グリッド列要素の名前です。グリッドでクエリーを使用する場合、この属性は、グリッド列に挿入するクエリー列の名前でなければなりません。

HEADER |
| オプション、
| すべて
Default value: "yes" 列ヘッダのテキストです。cfgrid の colHeaders 属性が true (デフォルト) の場合にのみ使用します。

WIDTH |
| オプション、
| すべて
Default value: "列ヘッダの幅" 列の幅です (単位 : ピクセル)。

TYPE |
| オプション、
| すべて
Default value: " " すべての形式で次の値を指定することができます。 image: グリッドには、列内の URL で指定されたイメージが表示されます。相対 URL を使用する場合、イメージは CFIDEclasses ディレクトリまたはサブディレクトリに置かれている必要があります。イメージが列セルよりも大きい場合は、セル内に収まるように切り取られます。Flash のイメージは JPEG ファイルでなければなりません。アプレット形式のイメージは JPEG ファイルか GIF ファイルです。 boolean: 列をチェックボックスとして表示します。セルが編集可能である場合、ユーザーはチェックマークを変更できます。 numeric: グリッドデータを数値でソートできます。 string_noCase: 大文字小文字を区別しないテキストとしてグリッドデータをソートできます。 アプレット形式では次の属性を指定できます。ただし、この属性は Flash 形式のグリッドでは機能しません。 image: 列の値では、イメージファイルへのパスを使用する以外に、ColdFusion の次のビルトインイメージ名を使用することもできます。 - cd - computer - document - element - folder - floppy - fixed - remote Flash 形式では次の属性を指定できます。ただし、この属性はアプレット形式のグリッドでは機能しません。 currency: 列データを通貨として形式設定します。小数点を基準に整列します。この列を使用するグリッドをソートすると、通貨について正しくソートされます。mask 属性を使用して通貨記号を指定します。デフォルトの通貨記号はドル記号 ($) です。

DISPLAY |
| オプション、
| すべて
Default value: "yes" yes no: 列を非表示にします。

SELECT |
| オプション、
| すべて
Default value: "yes" cfgrid の selectmode 属性の値が column、edit、または single の場合の選択動作を指定します。row や browse の場合は無視されます。 yes: ユーザーは selectmode 属性での指定に応じて、列を選択するか、列内のセルを選択または編集することができます。 no: ユーザーは列を選択することも、列内のセルを選択または編集することもできません。

FONT |
| オプション、
| すべて
Default value: "cfgrid で指定した値" 列内のデータのフォントです。

FONTSIZE |
| オプション、
| すべて
Default value: "cfgrid で指定した値" 列内のテキストのサイズです。

ITALIC |
| オプション、
| すべて
Default value: "cfgrid で指定した値" yes: グリッドコントロールのテキストをイタリックで表示します。 no

BOLD |
| オプション、
| すべて
Default value: "cfgrid で指定した値" yes: グリッドコントロールのテキストをボールドで表示します。 no

TEXTCOLOR |
| オプション、
| すべて
列内のグリッド要素のテキストの色です。16 進数の値またはテキスト名で指定します。 16 進数の値を入力するには、"##xxxxxx" という形式を使用します。ここで、x は 0 ～ 9 または A ～ F です。シャープ記号は、2 つ使用するか、または使用しません。 16 進数形式の任意の色 Black Red Blue Magenta Cyan Orange Darkgray Pink Gray White Lightgray Yellow

BGCOLOR |
| オプション、
| すべて
グリッド列の背景の色です。 オプション : textColor 属性の場合と同じです。

DATAALIGN |
| オプション、
| すべて
Default value: "cfgrid で指定した値" 列データの配置です。 Left Right Center

MASK |
| オプション、 Flash
フォームに表示される文字パターン、またはユーザーが入力して ColdFusion に送信できる文字パターンを制御するマスクパターンです。 通貨の type 属性がある列の場合、mask は通貨記号を指定します。ColdFusion MX は、数値の前に通貨記号を自動的に挿入します。 テキスト値や数値がある列の場合、mask は表示する形式またはユーザーが入力できる形式を、次のように指定します。 A = [A-Za-z] X = [A-Za-z0-9] 9 = [0-9] ? = 任意の文字 これら以外のすべての文字 = リテラル文字を挿入 列の値が日付またはタイムスタンプの場合、ColdFusion はこのマスクパターンを使用して、選択された日付を形式設定します。 日付時刻のマスク形式の詳細については、mask 属性の日付時刻形式を参照してください。

HREF |
| オプション、
| アプレット
URL、または各グリッド列のハイパーリンク先 URL を含んでいるクエリー列の名前です。

HREFKEY |
| オプション、
| アプレット
列の値の代わりに、各列の href URL に追加される値として使用するクエリー列です。

TARGET |
| オプション、
| アプレット
href で指定されたリンクを開くためのフレームです。

HEADERFONT |
| オプション、
| アプレット
Default value: "cfgrid で指定した値" 列ヘッダのフォントです。

HEADERFONTSIZE |
| オプション、
| アプレット
Default value: "cfgrid で指定した値" 列ヘッダのテキストのサイズです (単位 : ピクセル)。

HEADERITALIC |
| オプション、
| アプレット
Default value: "cfgrid で指定した値" yes: 列ヘッダをイタリックで表示します。 no

HEADERBOLD |
| オプション、
| アプレット
Default value: "cfgrid で指定した値" yes: ヘッダをボールドで表示します。 no

HEADERTEXTCOLOR |
| オプション、
| アプレット
グリッドコントロールの列ヘッダのテキストの色です。 オプション: textColor 属性の場合と同じです。

HEADERALIGN |
| オプション、
| アプレット
Default value: "cfgrid で指定した値" 列ヘッダのテキストの配置です。 Left Right Center

NUMBERFORMAT |
| オプション、
| アプレット
グリッド内で数値データを表示するための形式です。196ページの「numberFormat のマスク文字」 を参照してください。

VALUES |
| オプション、
| アプレット
列内のセルをドロップダウンリストボックスの形式にします。ドロップダウンリストの項目を指定します。例 :
    values = "arthur, scott, charles, 1-20, mabel"

VALUESDISPLAY |
| オプション、
| アプレット
values 属性内の要素を、ドロップダウンリストで表示する文字列にマッピングします。文字列や数値の範囲を区切り文字で区切って指定します。

VALUESDELIMITER |
| オプション、
| アプレット
Default value: ", [カンマ]" values 属性と valuesDisplay 属性の区切り文字です。