CFTIMER |
説明 CFML コードの指定されたセクションの実行時間を表示します。ColdFusion MX では、時間コードによって生成されたすべての出力と共にタイミング情報が表示されます。
メモ: | このタグを実行できるようにするには、ColdFusion MX Administrator で [デバッグの設定] の [タイマー情報] を有効にする必要があります。
カテゴリ デバッグタグ
シンタックス
    <cftimer
       label = "text"
       type = "inline"、"outline"、"comment"、"debug" >

       SQL ステートメント

    </cftimer>
関連項目 cfdump、cftrace、『ColdFusion MX 開発ガイド』の第18章の「アプリケーションのデバッグとトラブルシューティング」
ヒストリ ColdFusion MX 7: このタグが追加されました。
使用方法 このタグを使用して、コードブロックの実行時間を確認することができます。cftimer タグをネストできます。 このタグは、アプリケーション開発時の CFML コードのデバッグに役立ちます。本番環境では、ColdFusion MX Administrator でデバッグオプションを無効にしている限り、cftimer タグをコード内にそのまま残すことができます。
例
    ...
    <!--- type="inline"> --->
         <cftimer label="時間をクエリーし、インラインでループ処理" type="inline">
          <cfquery name="empquery" datasource="cfdocexamples">
                select *
                from Employees
          </cfquery>

          <cfloop query="empquery">
            <cfoutput>#lastname#, #firstname#</cfoutput><br>
          </cfloop>
       </cftimer>
    <hr><br>

    <!--- type="outline" --->
         <cftimer label="時間をクエリーし、アウトラインで CFOUTPUT を実行" type="outline">
          <cfquery name="coursequery" datasource="cfdocexamples">
                select *
                from CourseList
          </cfquery>
       <table border="1" width="100%">
          <cfoutput query="coursequery">
          <tr>
          <td>#Course_ID#</td>
          <td>#CorName#</td>
          <td>#CorLevel#</td>
          </tr>
          </cfoutput>
          </table>
       </cftimer>
    <hr><br>

    <!--- type="comment" --->
         <cftimer label="時間をクエリーし、コメントに CFOUTPUT を実行" type="comment">
          <cfquery name="parkquery" datasource="cfdocexamples">
                select *
                from Parks
          </cfquery>
            <p>[ビュー]-[Source] を選択して時間情報を確認します。</p>
           <table border="1" width="100%">
          <cfoutput query="parkquery">
          <tr>
          <td>#Parkname#</td>
          </tr>
          </cfoutput>
          </table>
       </cftimer>
    <hr><br>

    <!--- type="debug" --->
         <cftimer label="時間をクエリーし、デバッグ出力に CFOUTPUT を実行" type="debug">
          <cfquery name="deptquery" datasource="cfdocexamples">
                select *
                from Departments
          </cfquery>
            <p>時間情報を表示するには、CFTimer Times ヘッダまでスクロールする</p>
           <table border="1" width="100%">
          <cfoutput query="deptquery">
          <tr>
          <td>#Dept_ID#</td>
          <td>#Dept_Name#</td>
          </tr>
          </cfoutput>
          </table>
       </cftimer>
    ...

LABEL |
| オプション
Default value: "" "" 時間情報と共に表示するラベルです。

TYPE |
| オプション
Default value: "debug" inline: 結果 HTML に続いて、時間情報をインラインで表示します。 outline: 時間情報を表示し、時間コードによって作成された出力の周囲の行も表示します。ブラウザが FIELDSET タグをサポートしてアウトラインを表示できる必要があります。 comment: <!-- label: elapsed-time ms --> という形式で、HTML コメントに時間情報を表示します。デフォルトのラベルは cftimer です。 debug: CFTimer Times ヘッダの下のデバッグ出力に時間情報を表示します。