GETLOCALEDISPLAYNAME |
説明 ロケール値を取得し、それぞれのロケールに適した方法でその名前を表示します。デフォルトでは、現在のロケールをそのロケールの言語で取得します。
戻り値 指定されたロケールの言語で表記されたロケールの表示名
カテゴリ 表示および書式制御関数、各国語対応関数、システム関数
関数のシンタックス
    GetLocaleDisplayName([locale[, inLocale]])
関連項目 GetLocale、SetLocale
ヒストリ ColdFusion MX 7: この関数が追加されました。
パラメータ
例 次の例では、GetLocale の例を展開し、GetLocaleDisplayName 関数を使用して現在のロケールまたはその他のロケールでロケール名を表示する方法を示しています。サポートされるすべてのロケールからロケールを選択することが可能です。ColdFusion MX ロケールは選択されたロケールに変更され、新旧のロケール名が表示されます。
    <html>
    <head>
       <title>ロケールの表示</title>
    </head>

    <body>
    <h3>例 : ロケールの変更と表示</h3>
    <cfoutput>
       <!--- 新規リクエストごとに、ロケールを JVM ロケールにリセット --->
       初期ロケールの ColdFusion 名 : #GetLocale()#<br>
       初期ロケールの表示名 : #GetLocaleDisplayName()#<br>
       <br>
       <!--- これはフォームが送信された場合にのみ実行します。 --->
       <cfif IsDefined("form.mylocale")>
          <b>ロケールを #form.mylocale# に変更</b><br>
          <br>
          <!--- ロケールを送信された値に設定します。
             SetLocale は、以前の ColdFusion ロケール名を返します。  --->
          <cfset oldlocale=SetLocale("#form.mylocale#")>
          <!--- 現在のロケールの ColdFusion 名を取得します。
             ロケールが変更されているはずです。 --->
          <cfset newlocale=GetLocale()>
          新しいロケールの ColdFusion 名 : #newlocale#<br>
          現在のロケールで表記された新しいロケールの表示名 : #GetLocaleDisplayName()#<br>
          以前のロケールで表記された新しいロケールの表示名 :
             #GetLocaleDisplayName(newlocale, oldlocale)#<br>
          en_US で表記された新しいロケールの表示名 :
             #GetLocaleDisplayName(newlocale, "en_US")#<br>
          <br>
          現在のロケールで表記された以前のロケールの表示名 :
             #GetLocaleDisplayName(oldlocale)#<br>
          en_US で表記された以前のロケールの表示名 :
             #GetLocaleDisplayName(oldlocale, "en_US")#<br>
       </cfif>

       <!--- 自動送信フォームで新しいロケールを選択します。 --->
       <cfform>
          <h3>新しいロケールを選択してください :</h3>
          <cfselect name="mylocale">
             <!--- 変数 server.coldfusion.supportedlocales は
                   サポートされるすべてのロケール名のリストです。リスト cfloop タグを使用して、
                   リスト内のそれぞれの名前の HTML オプションタグを作成します。 --->
             <cfloop index="i" list="#server.coldfusion.supportedlocales#">
             <!--- 選択ボックスでは、米国英語によるロケールの表示名を
                   使用します。en_US を任意のロケールに変更できます。 --->
                <option value="#i#">#GetLocaleDisplayName(i, "en_US")#</option>
             </cfloop>
          </cfselect><br>
          <br>
          <cfinput type="submit" name="submitit" value="Change Locale">
       </cfform>
    </cfoutput>

    </body>
    </html>

LOCALE |
必要な名前を表記するロケールです。デフォルト値は、現在の ColdFusion のロケールです。 ColdFusion のロケールが設定されていない場合は、JVM のロケールです。

INLOCALE |
名前を返す際に使われるロケールです。デフォルト値は、現在の ColdFusion のロケールです。 ColdFusion のロケールが設定されていない場合は、JVM のロケールです。