local-name() 関数 |
パラメータノードセットの最初のノードのローカル部分を返します。
入力
ノードセット。ノードセットが空の場合、この関数は空の文字列を返します。ノードセットを省略した場合、この関数はコンテキストノードをその唯一のメンバーとしてノードセットを使用します。
出力
パラメータノードセットの最初の要素のローカル名に対応する文字列。ノードセットが空の場合、local-name() 関数は空の文字列を返します。
定義先
XPath 4.1 節「ノードセット関数」
例
document() 関数を使用して固有のノードをすべて処理するスタイルシートを次に示します。次に、各ノードに対して local-name() 関数を呼び出します。
    <?xml version="1.0"?>
    <xsl:stylesheet version="1.0"
      xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
      xmlns:months="Lookup table for month names">

      <months:name sequence="12">December</months:name>
      <months:name sequence="01">January</months:name>
      <months:name sequence="02">February</months:name>
      <months:name sequence="03">March</months:name>
      <months:name sequence="04">April</months:name>
      <months:name sequence="05">May</months:name>
      <months:name sequence="06">June</months:name>
      <months:name sequence="07">July</months:name>
      <months:name sequence="08">August</months:name>
      <months:name sequence="09">September</months:name>
      <months:name sequence="10">October</months:name>
      <months:name sequence="11">November</months:name>

      <xsl:output method="text"/>

      <xsl:variable name="newline">
    <xsl:text>
    </xsl:text>
      </xsl:variable>

      <xsl:template match="/">
        <xsl:value-of select="$newline"/>
        <xsl:text>A test of the local-name() function:</xsl:text>

        <xsl:value-of select="$newline"/>
        <xsl:value-of select="$newline"/>
        <xsl:for-each select="document('')//*">
          <xsl:text>local-name: </xsl:text>
          <xsl:value-of select="local-name()"/>
          <xsl:value-of select="$newline"/>
        </xsl:for-each>
      </xsl:template>

    </xsl:stylesheet>
このスタイルシートからは、次のような結果が生成されます。
    A test of the local-name() function:

    local-name: stylesheet
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: name
    local-name: output
    local-name: variable
    local-name: text
    local-name: template
    local-name: value-of
    local-name: text
    local-name: value-of
    local-name: value-of
    local-name: for-each
    local-name: text
    local-name: value-of
    local-name: value-of