format-number() 関数 |
数値を受け取り、それを文字列としてフォーマットします。
入力
フォーマットする数値とフォーマットパターン文字列が必須です。3 番目のパラメータは、小数点フォーマットの省略可能な名前です。3 番目のパラメータを指定しない場合、デフォルトの小数点フォーマットが使用されます。
出力
他のパラメータで指定された規則に従ってフォーマットされた数値。2 番目のパラメータで使用された特殊文字を次に示します。 # 桁を表します。先頭または末尾の 0 は表示されません。数値 4.0 を文字列 "#.##" を使用してフォーマットすると、文字列 "4" が返されます。 0 桁を表します。 # 文字とは異なり、 0 は常に 0 を表示します。数値 4.1 を文字列 "#.00" を使用してフォーマットすると、文字列 "4.10" が返されます。 . 小数点を表します。 - マイナス記号を表します。 , グループの区切り文字です。 ; 正の数のパターンを負の数のパターンから区別します。 % 数値をパーセント値で表示することを示します。この値に 100 が掛けられ、パーセント値で表示されます。数値 .76 を文字列 "##%" を使用してフォーマットすると、文字列 "76%" が返されます。 \u2030 千単位記号の Unicode 文字です。この値に 1000 が掛けられ、千単位で表示されます。数値 .768 を文字列 "###\u2030" を使用してフォーマットすると、文字列 "768" が返されます。 3 番目のパラメータを指定する場合は、<xsl:decimal-format> 要素の名前である必要があります。<xsl:decimal-format> 要素を使用すると、小数点とグループ区切り文字に使用する文字、無限大を表すために使用する文字列、およびその他のフォーマットオプションを定義できます。詳細については、<xsl:decimal-format> の説明を参照してください。
定義先
XSLT 12.3 節「Number Formatting」
例
次のスタイルシートは、format-number() 関数をさまざまな方法で使用します。
    <?xml version="1.0" encoding="ISO-8859-1" ?>
    <xsl:stylesheet version="1.0"
      xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
      xmlns:months="Lookup table for month names">

      <xsl:output method="text"/>

      <months:name sequence="01">January</months:name>
      <months:name sequence="02">February</months:name>
      <months:name sequence="03">March</months:name>
      <months:name sequence="04">April</months:name>

      <xsl:variable name="newline">
    <xsl:text>
    </xsl:text>
      </xsl:variable>

      <xsl:decimal-format name="f1"
        decimal-separator=":"
        grouping-separator="/"/>

      <xsl:decimal-format name="f2"
        infinity="Really, really big"
        NaN="[not a number]"/>

      <xsl:template match="/">
        <xsl:value-of select="$newline"/>
        <xsl:text>Tests of the format-number() function:</xsl:text>

        <xsl:value-of select="$newline"/>
        <xsl:value-of select="$newline"/>
        <xsl:text>   format-number(528.3, '#.#;-#.#')=</xsl:text>
        <xsl:value-of select="format-number(528.3, '#.#;-#.#')"/>
        <xsl:value-of select="$newline"/>
        <xsl:text>   format-number(528.3, '0,000.00;-0,000.00')=</xsl:text>
        <xsl:value-of select="format-number(528.3, '0,000.00;-0,000.00')"/>
        <xsl:value-of select="$newline"/>
        <xsl:text>   format-number(-23528.3, '$#,###.00;($#,###.00)')=</xsl:text>
        <xsl:value-of select="format-number(-23528.3, '$#,###.00;($#,###.00)')"/>
        <xsl:value-of select="$newline"/>
        <xsl:text>   format-number(1528.3, '#/###:00', 'f1')=</xsl:text>
        <xsl:value-of select="format-number(1528.3, '#/###:00;-#/###:00', 'f1')"/>
        <xsl:value-of select="$newline"/>
        <xsl:text>   format-number(1 div 0, '###,###.00', 'f2')=</xsl:text>
        <xsl:value-of select="format-number(1 div 0, '###,###.00', 'f2')"/>
        <xsl:value-of select="$newline"/>
        <xsl:text>   format-number(blue div orange, '#.##', 'f2')=</xsl:text>
        <xsl:value-of select="format-number(blue div orange, '#.##', 'f2')"/>
        <xsl:value-of select="$newline"/>
        <xsl:value-of select="$newline"/>
        <xsl:for-each select="report/month">
          <xsl:text>   </xsl:text>
          <xsl:value-of
            select="document('')/*/months:name[@sequence=current()/@sequence]"/>
          <xsl:text> - </xsl:text>
          <xsl:value-of select="format-number(miles-flown, '##,###')"/>
          <xsl:text> miles flown, </xsl:text>
          <xsl:value-of select="format-number(miles-earned, '##,###')"/>
          <xsl:text> miles earned.</xsl:text>
          <xsl:value-of select="$newline"/>
          <xsl:text>     (</xsl:text>
          <xsl:value-of
            select="format-number(miles-flown div sum(//miles-flown), '##%')"/>
          <xsl:text> of all miles flown, </xsl:text>
          <xsl:value-of
            select="format-number(miles-earned div sum(//miles-earned), '##%')"/>
          <xsl:text> of all miles earned.)</xsl:text>
          <xsl:value-of select="$newline"/>
          <xsl:value-of select="$newline"/>
        </xsl:for-each>
        <xsl:text>   Total miles flown: </xsl:text>
        <xsl:value-of select="format-number(sum(//miles-flown), '##,###')"/>
        <xsl:text>, total miles earned: </xsl:text>
        <xsl:value-of select="format-number(sum(//miles-earned), '##,###')"/>
      </xsl:template>

    </xsl:stylesheet>
この XML ドキュメントをスタイルシートとして使用します。
    <?xml version="1.0"?>
    <report>
      <title>Miles Flown in 2001</title>
      <month sequence="01">
        <miles-flown>12379</miles-flown>
        <miles-earned>35215</miles-earned>
      </month>
      <month sequence="02">
        <miles-flown>32857</miles-flown>
        <miles-earned>92731</miles-earned>
      </month>
      <month sequence="03">
        <miles-flown>19920</miles-flown>
        <miles-earned>76725</miles-earned>
      </month>
      <month sequence="04">
        <miles-flown>18903</miles-flown>
        <miles-earned>31781</miles-earned>
      </month>
    </report>
このスタイルシートを実行した場合の結果は次のとおりです。
    Tests of the format-number() function:

       format-number(528.3, '#.#;-#.#')=528.3
       format-number(528.3, '0,000.00;-0,000.00')=0,528.30
       format-number(-23528.3, '$#,###.00;($#,###.00)')=($23,528.30)
       format-number(1528.3, '#/###:00', 'f1')=1/528:30
       format-number(1 div 0, '###,###.00', 'f2')=Really, really big
       format-number(blue div orange, '#.##', 'f2')=[not a number]

       January - 12,379 miles flown, 35,215 miles earned.
         (15% of all miles flown, 15% of all miles earned.)

       February - 32,857 miles flown, 92,731 miles earned.
         (39% of all miles flown, 39% of all miles earned.)

       March - 19,920 miles flown, 76,725 miles earned.
         (24% of all miles flown, 32% of all miles earned.)

       April - 18,903 miles flown, 31,781 miles earned.
         (22% of all miles flown, 13% of all miles earned.)

       Total miles flown: 84,059, total miles earned: 236,452
最初のいくつかの例は、利用できるさらに複雑なフォーマットオプションの一部と、スタイルシートの <xsl:decimal-format> 要素の参照を示しています。最後のセクションは、format-number 関数のより標準的な使用である、選択された値または XML ドキュメントから計算された値のフォーマットについて説明しています。